wPDF features

RobinP

Hi,

Could you confim a couple of things about wPDF for me please:

1. Can I use it without having WPTools?
2. Can I export any amount (possibly many pages) of RTF text from a standard TRichEdit to a PDF, and if so will this do proper RTF to PDF text conversion? (Fast Reports does this by converting the RTF to an image, which is not acceptable for my project).

Regards,
Robin

support

Hi,

>> 1. Can I use it without having WPTools?

Yes. It is basically a metafile (EMF) to PDF converter. It provides a Canvas which is a TMetafileCanvas.

>>2. Can I export any amount (possibly many pages) of RTF text from a standard TRichEdit to a PDF, and if so will this do proper RTF to PDF text conversion? (Fast Reports does this by converting the RTF to an image, which is not acceptable for my project). <<

It can export what TRichEdit prints, but only that. So it is limited to the features the RichEd.DLL offers. It will create text, not an image.

This is the sample code to export from a RichEdit:

Code

procedure RichEditPDFPrint(RichEditHandle : Cardinal;
  PageWidth, PageHeight, LeftMargin, TopMargin, RightMargin, BottomMargin : Extended;
  UseCM : Boolean; PDFPrinter : TWPCustomPDFExport);
const
  EM_FORMATRANGE = WM_USER + 57;
type
  TRichCharRange = record
    cpMin: Longint;
    cpMax: LongInt;
  end;
  TRichFormatRange = record
    hdc: HDC;
    hdcTarget: HDC;
    rc: TRect;
    rcPage: TRect;
    chrg: TRichCharRange;
  end;
var
  Range: TRichFormatRange;
  LastChar, MaxLen, LogX, LogY, OldMap, PageW, PageH: Integer;
  PageRect: TRect;
  DC : HDC;
begin
  FillChar(Range, SizeOf(TRichFormatRange), 0);
  DC := GetDC(0);
  LogX := GetDeviceCaps(DC, LOGPIXELSX);
  LogY := GetDeviceCaps(DC, LOGPIXELSY);
  try
    PDFPrinter.BeginDoc;
    // Initialize Page and output parameter
    if UseCM then
    begin
     PageW := Round( PageWidth * LogX / 2.54);
     PageH := Round( PageHeight * LogY / 2.54);
     PageRect.Left := Round( LeftMargin * 1440 / 2.54);
     PageRect.Right := Round( (PageWidth-RightMargin) * 1440 / 2.54);
     PageRect.Top := Round( TopMargin * 1440 / 2.54);
     PageRect.Bottom := Round( (PageHeight-BottomMargin) * 1440 / 2.54);
    end else
    begin
     PageW := Round( PageWidth * LogX);
     PageH := Round( PageHeight * LogY);
     PageRect.Left := Round( LeftMargin * 1440);
     PageRect.Right := Round( (PageWidth-RightMargin) * 1440);
     PageRect.Top := Round( TopMargin * 1440);
     PageRect.Bottom := Round( (PageHeight-BottomMargin) * 1440);
    end;
    // Initilaize Format Parameters
    LastChar := 0;
    MaxLen := SendMessage(RichEditHandle, WM_GETTEXTLENGTH, 0, 0);
    Range.rcPage := PageRect;
    Range.chrg.cpMax := -1;
    Range.hdcTarget := DC;
    Range.hdc := DC;
    SendMessage(RichEditHandle, EM_FORMATRANGE, 0, 0);    
    try
      repeat
        PDFPrinter.StartPage(PageW,PageH,LogX, LogY, 0);
        Range.rc := PageRect;
        Range.chrg.cpMin := LastChar;
        Range.hdcTarget := PDFPrinter.Canvas.Handle;
        Range.hdc := PDFPrinter.Canvas.Handle;
        LastChar := SendMessage(RichEditHandle, EM_FORMATRANGE, 1, Longint(@Range));
        PDFPrinter.EndPage;
      until (LastChar >= MaxLen) or (LastChar = -1);
      PDFPrinter.EndDoc;
    finally
      SendMessage(RichEditHandle, EM_FORMATRANGE, 0, 0);  // flush buffer
    end;
  finally
    ReleaseDC(0,DC);
  end;
end;

Alles anzeigen

RobinP

OK, this looks like it will do what I need. I couldn't get the demo working for C++ Builder, but I think I now have enough to persuade my boss to buy a licence so we can try it out properly.
Thanks for the detailed reply.
Cheers,
Robin.