AV bei Melmerge, wenn BlobField leer ist

procedure TWPMMDataProvider.DoMergeGetText(Sender: TObject;
    ...
    end else if (field is TGraphicField) or isBMP then
    begin
      Done := TRUE;
      if field.isnull then // sonst AV
        Contents.StringValue := ''
      else
      begin
        ...
              TWPOImage(obj).HeightTW :=
                MulDiv(TWPOImage(obj).Graphic.Height, 1440, 96); // hier kommt AV, da TWPOImage(obj).Graphic dann nil ist
        ...
      end;
    ...

procedure TWPMMDataProvider.DoMergeGetText(Sender: TObject;
  const fieldname: string; Contents: TWPMMInsertTextContents);
var
  field: TField;
  dataset: TDataset;
  done: Boolean;
  obj: TWPOImage;
  isnew: Boolean;
  isBMP, isRTF: Boolean;
  s: string;
  i: Integer;
  blobstream: TStream;
  function FindInList(list: TStringList): Boolean;
  var
    ii: Integer;
  begin
    Result := FALSE;
    for ii := 0 to list.Count - 1 do
      if CompareText(fieldname, list[ii]) = 0 then
      begin Result := TRUE;
        break;
      end;
  end;
begin
  if FNowWriteData and FShowFieldNames then
    exit; // not allowed !
  // ---------- EditField, the end marks should not be used for mailmerge ! ----
  if Contents.c = WPEditFieldEnd then
    exit;
  if Contents.c = WPEditFieldStart then
    Contents.Options := [mmDeleteUntilFieldEnd];
  // ---------------------------------------------------------------------------
  dataset := FDataLink.DataSet;
  Done := FALSE;
  if assigned(FOnGetDataset) then
  begin
    FOnGetDataset(Self, fieldname, Contents, dataset);
    if dataset = nil then exit;
  end;
  // ---------------------------------------------------------------------------
  s := '';
  isBMP := FindInList(FBMPFields);
  isRTF := not isBMP and FindInList(FRTFFields);
  if FNowWriteData then
  begin
    if dataset <> nil then
    begin
      field := dataset.FindField(fieldname);
      if assigned(FSaveFielddata) then
      begin
        if (field is TGraphicField) or isBMP then
          s := ''
        else
          if (FRTFFieldList.IndexOf(UpperCase(fieldname)) < 0) and not isRTF then // use last loaded format !
            //  if Contents.OldIsPlain then
            s := Contents.OldText
          else
            s := Contents.OldFormattedText;
        FSaveFielddata(Self, fieldname, contents, s, field, done);
        if done then
          exit
        else
          if not (field is TGraphicField) and not isBMP and (field <> nil) then
            field.AsString := s;
      end
      else
        if not (field is TGraphicField) and (field <> nil) and not isBMP then
        begin
          if not isRTF and (FRTFFieldList.IndexOf(UpperCase(fieldname)) < 0) then // use last loaded format !
            s := Contents.OldText
          else
            s := Contents.OldFormattedText;
          field.AsString := s;
        end;
    end;
    exit;
  end;
  // ---------------------------------------------------------------------------
  if assigned(FGetTextToInsert) then
  begin
    FGetTextToInsert(Self, fieldname, contents, done);
    if done then
      exit;
  end;
  Contents.StringValue := '';
  if (dataset <> nil) and dataset.Active then
  begin
    field := dataset.FindField(fieldname);
    if FShowFieldNames then
    begin
      if field <> nil then
        Contents.StringValue := field.DisplayName
      else
        Contents.StringValue := fieldname;
      if FAppendSpaceToNonEmpty and (Contents.StringValue <> '') then
        Contents.StringValue := Contents.StringValue + #32;
      // Done := TRUE;
      Done := (field <> nil); // further next dataset
    end
    else
      if (field = nil) {otherwise AV} or field.IsNull {otherwise AV with images} then
      begin
        done := (field <> nil); // further next dataset
        Contents.StringValue := '';
      end
      else
        if (field is TGraphicField) or isBMP then
        begin
          Done := TRUE;
          if (wpmmPreserveObjectSize in FOptions) and
            (Contents.CurrentObject <> nil) and
            (Contents.CurrentObject is TWPOImage) then
          begin
            obj := TWPOImage(Contents.CurrentObject);
            isnew := FALSE;
          end
          else
          begin
            obj := CreateTWPTOClass(
              (Sender as TWPCustomRtfEdit).Memo.RTFData
              , 'BMP') as TWPOImage;
            isnew := TRUE;
          end;
          if obj <> nil then
          begin
            // TWPOImage(obj).Graphic.Width := 10;
            if field is TGraphicField then
              TWPOImage(obj).Picture.Assign(field)
            else
              if field is TBlobField then
              begin
                blobstream := TMemoryStream.Create;
                try
                  TBlobField(field).SaveToStream(blobstream);
                  blobstream.Position := 0;
                  TWPOImage(obj).FileExtension := 'BMP';
                  TWPOImage(obj).LoadFromStream(blobstream);
                except
                 // We don't want to see any image errors here !
                end;
                blobstream.Free;
              end;
            if isnew then
            begin
              TWPOImage(obj).HeightTW := MulDiv(TWPOImage(obj).Graphic.Height, 1440, 96);
              TWPOImage(obj).WidthTW := MulDiv(TWPOImage(obj).Graphic.Width, 1440, 96);
            end;
            TWPOImage(obj).WriteRTFMode := wobOnlyRTF;
            Contents.obj := obj;
          end;
        end
        else
        if field <> nil then
        begin
          Done := TRUE;
          if field.IsNull then
            Contents.StringValue := ''
          else
          try
            Contents.StringValue := field.AsString;
            i := FRTFFieldList.IndexOf(Uppercase(fieldname));
            if (Copy(Contents.StringValue, 1, 5) = '{\rtf') then
            begin
            // Attention, we will loos the formatting !
              if wpmmConvertRTFToANSI in FOptions then
                Contents.StringValue := WPToolsRTFToANSI(Contents.StringValue);
            // we want to save as RTF since it was in this format !
              if i <0>= 0) then
                FRTFFieldList.Delete(i);
              if FAppendSpaceToNonEmpty and (Contents.StringValue <> '') then
                Contents.StringValue := Contents.StringValue + #32;
            end;
          except
         // If we have a problem create a message but don't hurt further operation
            on e: Exception do Contents.StringValue := 'ERROR:' + e.Message;
          end;
        end;
  end
  else
    if FShowFieldNames then
    begin
      Done := TRUE;
      Contents.StringValue := fieldname;
    end;


  if not Done and assigned(FNextDataProvider) and (FNextDataProvider <> Self) then
    FNextDataProvider.DoMergeGetText(Sender, FieldName, Contents);
end;