Problems with saving and loading objects

Sleep

Hi,
I have troubles with save/load functions in WPTools v 4.25. Steps to reproduce:

1. Create text and insert OLE object (Equation).
2. After the OLE object put some text.
3. Then insert another OLE object and text.
4. Then insert some image and text.
5. Then insert third OLE object.

Than save the text.

If you load this texxt into WPTools (including your demo WordProcessor.exe) the firtst OLE objects is loaded correctly, the image is visible too, but the third OLE object is gone. Please help me with this problem. In RTF document is all three OLE objects saved correctly.

You can download the saved document at adress . http://www.dosli.cz/soubory/wptools/test.zip.

Thanks for your help

Petr Slipek
Dosli

support

The OLE Container is proprietary to V4, I cannot recomend to use it since the created files nobody else can read. YOu shoukld created your formulas in a popup form which uses ONE OLEContainer and insert the image as metafile.

Sleep

If I use custom form to create equations with OLE container, I am able to save its content to wptools image as metafile.

Is there any way to save original data of the OLE container within wptools rtf text to be able to modify metafile later?

Petr Slipek.

support

Hi,

Yes, you can do that. You need to attach a blob property to the image object and save the program data with that.

The load/save works just as in Delphi VCL - the propertry must be published, reader and writer functions must be defined.

This code should be a good start:

Code

{ This is a graphics object with an attached 'BAG'.
  The bag is implemented as a stream object and is used to save
  the additional contents for the graphic.
}


interface


 uses Windows, Forms, Classes, WPObj, WPDefs, WPEmOBJ, ActiveX, olectnrs, Graphics;


 type
   TWPPersistentStream = class(TPersistent)
   private
      FData : TMemoryStream;
   public
      property Stream : TMemoryStream read FData; 
      function Empty : Boolean;
      constructor Create;
      destructor Destroy; override;
      procedure  Assign(Source : TPersistent); override;
   protected
      procedure DefineProperties(Filer: TFiler); override;
      procedure ReadData(Stream: TStream); virtual;
      procedure WriteData(Stream: TStream); virtual;
   end;


   TWPOBagImage = Class(TWPOImage)
   private
     FContentsDef    : string;
     FContentsParams : string;
     FDataBag : TWPPersistentStream;
     function GetDataBag : TWPPersistentStream;
     procedure SetDataBag(x : TWPPersistentStream);
   public
      constructor Create(aOwner : TComponent); override;
      destructor Destroy; override;
      procedure UpdateMetafile(FOLE : TOLEContainer);
   published
     property DataBag : TWPPersistentStream read GetDataBag write SetDataBag;
     property ContentsDef    : string read FContentsDef write FContentsDef;
     property ContentsParams : string read FContentsParams write FContentsParams;
   end;


implementation


constructor TWPPersistentStream.Create;
begin
   inherited Create;
   FData := TMemoryStream.Create;
end;


destructor TWPPersistentStream.Destroy;
begin
    FData.Free;
    inherited Destroy;
end;


function TWPPersistentStream.Empty : Boolean;
begin Result := FData.Size=0; end;


procedure TWPPersistentStream.DefineProperties(Filer: TFiler);
begin
  Filer.DefineBinaryProperty('Data', ReadData, WriteData, not Empty);
end;


procedure TWPPersistentStream.ReadData(Stream: TStream);
begin
  FData.Clear;
  FData.LoadFromStream(Stream);
end;


procedure TWPPersistentStream.WriteData(Stream: TStream);
begin
  FData.SaveToStream(Stream);
end;


procedure TWPPersistentStream.Assign(Source : TPersistent);
begin
  if Source is TWPPersistentStream then
  begin
      FData.Clear;
      if (TWPPersistentStream(Source)<>nil) and
         not TWPPersistentStream(Source).Empty then
      begin
         TWPPersistentStream(Source).Stream.Position := 0;
         FData.LoadFromStream(  TWPPersistentStream(Source).Stream);
      end;
  end else inherited Assign(Source);
end;


function TWPOBagImage.GetDataBag : TWPPersistentStream;
begin
   Result := FDataBag;
end;


procedure TWPOBagImage.SetDataBag(x : TWPPersistentStream);
begin
   FDataBag.Assign(x);
end;


constructor TWPOBagImage.Create(aOwner : TComponent);
begin
  inherited Create(aOwner);
  FDataBag := TWPPersistentStream.Create;
end;


destructor TWPOBagImage.Destroy;
begin
   FDataBag.Free;
   inherited Destroy;
end;


procedure TWPOBagImage.UpdateMetafile(FOLE : TOLEContainer);
var
 aMetaFileCanvas : TMetafileCanvas;
 aMetafile : TMetafile;
 r : TRect;
begin
   aMetaFileCanvas := nil;
   if FOle<>nil then
   begin
     aMetafile := TMetafile.Create;
    try
     r.Left   := 0;
     r.Top    := 0;
     r.Right  := MulDiv(WidthTW,Screen.PixelsPerInch, 1440);
     r.Bottom := MulDiv(HeightTW,Screen.PixelsPerInch, 1440);
     aMetafile.Width := r.Right;
     aMetafile.Height := r.Bottom;
     aMetafileCanvas :=  TMetafileCanvas.Create(aMetafile, 0);
     OleDraw(FOle.OleObjectInterface, DVASPECT_CONTENT, aMetafileCanvas.Handle, r);
     aMetafileCanvas.Free;
     aMetafileCanvas := nil;
     if Picture.Graphic=nil then
        Picture.Graphic := TMetaFile.Create;
     Picture.Graphic.Assign(aMetafile);
    finally
     if aMetafileCanvas<>nil then aMetafileCanvas.Free;
     aMetafile.Free;
    end;
   end; 
end;


initialization
   WPRegisterClasses([TWPOBagImage]);
   WPORegisterFileExt('TWPOBagImage', '.OLE');
end.

Alles anzeigen

Julian

Sleep

Thanks, it helps a lot. I have another question. Is this code working with WPTools 5 or are there any changes. Just ordered WPTools 5 this week :-).

Petr Slípek

support

Hi,

The objects in V5 work as in V4 - as long as they do not have a window handle. There are not edits, memos or worse, embedded OLE container in V5. The reason for this is the requirement under the V5 concept that an object paints itself to different surfaces at different resolutions.

Julian

Problems with saving and loading objects

Ähnliche Themen

PNG Scrolls

WPTOOLS Changelog