WPTools 5: Mehrfach Drucken

martin_s

Hallo,

in meiner Anwendung verwende ich einen Standard TPrintDialog zum Drucken und führe dann eine Schleife über Copies (Anzahl der Ausdrucke) durch:

Code

for i := 0 to PrintDialog1.Copies - 1 do begin
      if PrintDialog1.PrintRange=prAllPages then
        WP.PrintParameter.PageRange:=wprAllPages
      else
        WP.PrintParameter.PageRange:=wprPageList;
      if WP.PrintParameter.PageRange=wprAllPages then
        WP.print
      else
        WP.PrintPages(PrintDialog1.FromPage, PrintDialog1.ToPage);
    end;

(WP ist ein TWPRichText-Objekt)
Mein Problem nun: Gebe ich als Anzahl 3 ein, wird bei manchen Druckertreibern in jedem Schleifendurchlauf dreimal gedruckt (also insgesamt neunmal). Bei meinem eigenen Drucker hingegen nur einmal pro Durchlauf.
Was mache ich falsch - bzw. wie druckt man mit WPTools richtig, so dass es möglichst überall gleich funktioniert?

Danke und Gruß,
Martin

support

Hello,

please see unit WPCtrRich

Code

function TWPCustomRichText.PrintDialog(PageRange: string = ''): Boolean;
{$IFDEF DISABLEPRINTER}
begin Result := FALSE;
end;
{$ELSE}
var
  dia: TPrintDialog;
  f, t, Copies, pw, ph: Integer;
  land, nh, nh2: Boolean;
  i: Integer;
  aPrintCtrl, aTempPrintCtrl: TWPCustomRTFEdit;
begin
  if WPNoPrinterInstalled then begin Result := FALSE; exit; end;
  if FIsDynamic then
    dia := TPrintDialog.Create(nil)
  else dia := TPrintDialog.Create(Self);




  Result := FALSE;
  nh := false;
{$IFDEF ALLOWWORDWRAPPRINT}
  nh2 := FALSE;
{$ELSE} // Need to change it NOW - otherwise the page count is not correct
  nh2 := WordWrap;
  if nh2 then
  begin
    WordWrap := FALSE;
    ReformatAll;
  end;
{$ENDIF}


  aTempPrintCtrl := nil;
  aPrintCtrl := Self;
  try
    if (IsSelected) and not (wpDontAllowSelectionPrinting in PrintParameter.PrintOptions) then
      dia.Options := [poPageNums, poSelection] //V5.18.1
    else
    begin // No text is selected, should we hide the merge fields?
      dia.Options := [poPageNums];
      if not InsertPointAttr.Hidden and (wpAlwaysHideFieldmarkers in PrintParameter.PrintOptions) then
      begin
        InsertPointAttr.Hidden := TRUE;
        ReformatAll;
        nh := TRUE;
      end;
    end;
    dia.PrintRange := prAllPages;
    dia.MinPage := 1;
    f := PageCount;
    if f <= 0 then f := 1;
    dia.MaxPage := f;
    dia.FromPage := 1;
    dia.ToPage := dia.MaxPage;
    dia.Copies := 1;
    dia.Collate := TRUE;


    UpdatePrinterProperties(Printer, 0); //V5.18.1 -  Inserted


    if FMemo.RTFData._LastReformatWasSpeedReformat then ReformatAll;
{$IFDEF USEEXECDIA}if ExecDialog(dia) then {$ELSE}
    if dia.Execute then {$ENDIF}
    begin
      if dia.PrintRange = prSelection then // Print the selected text
      begin
        aTempPrintCtrl := TWPCustomRTFEdit.CreateDynamic;
        // Option "-writeheaderfooter," would copy header+footer!
        aTempPrintCtrl.AsString := Self.AsANSIString('WPTOOLS', true);
        aTempPrintCtrl.AssignPrintProperties(Self);
        if wpAlwaysHideFieldmarkers in PrintParameter.PrintOptions then
          aTempPrintCtrl.InsertPointAttr.Hidden := TRUE;
        // This code would adjust the page numbering
        { aTempPrintCtrl.Memo.OverridePageCount := PageCount;
        aTempPrintCtrl.Memo.OverridePageOffset := Memo.GetPageWithSelectionStart;
        if aTempPrintCtrl.Memo.OverridePageOffset<0 then
           aTempPrintCtrl.Memo.OverridePageOffset := 0; }
        aTempPrintCtrl.ReformatAll; // Don't wait!
        aPrintCtrl := aTempPrintCtrl;
      end else // OK, no selection printing - NOW hide the merge fields!
      begin
        if not nh and not InsertPointAttr.Hidden and
          (wpAlwaysHideFieldmarkers in PrintParameter.PrintOptions) then
        begin
          InsertPointAttr.Hidden := TRUE;
          ReformatAll;
          nh := TRUE;
        end;
      end;


      pw := MulDiv(GetDeviceCaps(Printer.Handle, PHYSICALWIDTH), 1440,
        GetDeviceCaps(Printer.Handle, LOGPIXELSX));
      ph := MulDiv(GetDeviceCaps(Printer.Handle, PHYSICALHEIGHT), 1440,
        GetDeviceCaps(Printer.Handle, LOGPIXELSY));
      land := Printer.Orientation = poLandscape;


      // Update Page Size according to Printer --------------------------
      if (Abs(aPrintCtrl.Header.PageWidth - pw) < 2) or (Abs(aPrintCtrl.Header.PageHeight - ph) < 2)
        or (aPrintCtrl.Header.Landscape <> land) then
      begin
        aPrintCtrl.Header.BeginUpdate;
        aPrintCtrl.Header.Landscape := Printer.Orientation = poLandscape;
        aPrintCtrl.Header.PageWidth := pw;
        aPrintCtrl.Header.PageHeight := ph;
        aPrintCtrl.Header.EndUpdate;
        aPrintCtrl.ReformatAll; // Don't wait!
      end;
      // Update screeen ... (only if we are not printing the selection!)
      if aTempPrintCtrl = nil then
      begin
        FMemo._DBufferIsValid := FALSE;
        Paint;
        SetFocusValues(true);
      end;
      // PrintParameter.PageRange := wprAllPages;
      if dia.PrintRange = prAllPages then
      begin
        f := 1;
        t := aPrintCtrl.PageCount;
      end
      else {if dia.PrintRange=prPageNums  then   }
      begin
        f := dia.FromPage;
        t := dia.ToPage;
      end;
      if dia.Collate then
      begin
        Printer.Copies := 1;
        Copies := dia.Copies;
      end
      else
      begin
        Printer.Copies := dia.Copies;
        Copies := 1;
      end;
      for i := 1 to Copies do
      begin
        aPrintCtrl.PrintPages(f, t);
        Result := TRUE; // Copies =0 ???
      end;
    end;
  finally
    FreeAndNil(aTempPrintCtrl);
    dia.Free;
{$IFDEF ALLOWWORDWRAPPRINT}
    if nh2 then WordWrap := TRUE;
{$ENDIF}
    if nh and (wpAlwaysHideFieldmarkers in PrintParameter.PrintOptions) then
    begin
      InsertPointAttr.Hidden := FALSE;
      ReformatAll;
    end;
  end;
end;
{$ENDIF}

Alles anzeigen

The Printer.Copies is NOT used if "Collate" has been activated.