FMX: Autosize TFlowLayout

Instead of translating VCL a form to firemonkey, I find it more useful to recreate it using the best technique firemonkey has to offer.

Firemonkey layout controls are quite useful to create a form which realigns its controls when the size of the forms was changed. This is needed in case you do not know if the form would be used in landscape or portrait mode. But how to make the layout size itself according to its contents? Currently there does not seem to be an autosize property.

Fortunately there is the Resized event. If you assign an event handler which does the autosizing, it will work quite nicely. You can even place your

TFlowlayout inside of a TScrollbox so the form will display scrollbars as soon as required.

The event handler can be the same for all the layout controls and just needs one line of code:

procedure TForm1.AllFlowLayoutResized(Sender: TObject);
begin
   WPResizeTControlToContents( Sender as TControl );
end;

Of course the utility function WPResizeTControlToContents must be defined somewhere else in the project, preferably in a unit all the other units include.

The following code automatically checks the align property to disable horizontal/vertical sizing.

procedure WPResizeTControlToContents( AControl : TControl;
    Width : Boolean  = true;
    Height : Boolean = true );
var I : Integer; r : TRectF;
begin
  if AControl.Align in [TAlignLayout.Top, TAlignLayout.Bottom, TAlignLayout.MostTop, TAlignLayout.MostBottom,
     TAlignLayout.Client,
     TAlignLayout.Scale,
     TAlignLayout.Fit] then
        Width := false;
  if AControl.Align in [TAlignLayout.Left, TAlignLayout.Right, TAlignLayout.MostLeft, TAlignLayout.MostRight,
     TAlignLayout.Client,
     TAlignLayout.Scale, TAlignLayout.Fit] then
         Height := false;
  r := TRectF.Empty;
  for I := 0 to AControl.ChildrenCount-1 do
     if AControl.Children[I] is TControl then
         UnionRect(r, r, TControl(AControl.Children[I]).BoundsRect );
  if Width and Height then
        AControl.Size.Size := TSizeF.Create(r.Width, r.Height)
  else if Width then AControl.Width := r.Width
  else if Height then AControl.Height := r.Height;
end;

It is worth to note that only the first level of the children of the control are checked for size.

The function TControl.ChildrenRect btw did not work as expected.